Y Abi Musteraufgaben 🚧

23:59:47

pinMode(MENU_S,INPUT); // nicht unbedingt erforderlich da Userbutten PC13 PullUps hat
attachInterrupt (digitalPinToInterrupt (MENU_S), isr_Menu, FALLING);
pinMode(S2,INPUT_PULLDOWN); // PA1 auf Sturm-Board braucht Pulldown
attachInterrupt (digitalPinToInterrupt (S2), isr_S2, RISING);

// 32MHZ/3200 -> 10kHz 1/10kHz = 100µs 10000*100µs = 1s
/*sekTimer.setPrescaleFactor(3200); // 0-65535
  sekTimer.setOverflow(10000);    //0-65535 => Prescaler AKTIV!
*/
sekTimer.setOverflow(1, HERTZ_FORMAT); // lass die API rechnen

sekTimer.attachInterrupt(isr_sekTimer); // Interrupt einstellen

void incUhrzeit(){ // erhöht z_sek und passt z_min und z_std an
  z_sek++;
  if(z_sek>59){
    z_sek=0;
    z_min++;
    if(z_min>59){
      z_min=0;
      z_std++;
      if(z_std>23){
        z_std=0;
      }
    }
  }
}

void ausgebenLCD_Uhrzeit(){ // Uhrzeit wird in Zeile 1 ausgegeben
  lcd.setCursor(0,1);
  lcd.printf("%02u : %02u : %02u    ", z_std, z_min, z_sek);
}

void ausgebenLED_Sekunden(){ // Ausgabe auf PORTC 
  GPIOC->ODR= (z_sek/10)<<4 | z_sek%10;
}

void sendData (unsigned char msb, unsigned char lsb){ // Hilfsfunktion zur Datenuebertragung
  digitalWrite(CS, LOW); // Uebertragung beginnt
  SPI.transfer(msb); // 8 Bit Transfer MSB      
  SPI.transfer(lsb); // 8 Bit Transfer LSB
  //SPI.transfer16(msb<<8 | lsb); // 16 Bit Transfer
  digitalWrite(CS, HIGH); // Uebertragung fertig, uebernehme Daten!
}

pinMode(CS, OUTPUT); // CS-Pin initialisieren
digitalWrite(CS, HIGH); // bei SPI_MODE0 ist CS in Ruhe high
SPI.begin();  // SPI-Schnittstelle einrichten fuer MAX7219
SPI.setBitOrder(MSBFIRST);            // Hoechstwertiges Bit zuerst
SPI.setClockDivider(SPI_CLOCK_DIV32); // SCK mit 1 MHz, koennte auch 10 MHz
SPI.setDataMode(SPI_MODE0);           // SCK in Ruhe Low, Uebername bei steigender Flanke
delay(10); // kurz warten bis verdaut..
// MAX7219 Initialisierung des Chips
sendData(0x09, 0x00); // Decoding:     Aus: keine BCD Dekodierung fuer 7 Segment
sendData(0x0A, 0x05); // Intesity:     Helligkeit auf 5 von 15 einstellen
sendData(0x0B, 0x07); // Scan Limit:   Es sind 8 Zeilen mit LEDs
sendData(0x0C, 0x01); // Shutdown:     Bit0 = 1: Normal operation mode, kein Ruhezustand
sendData(0x0F, 0x00); // Display Test: Bit0 = 1: Displaytest An: Alle LEDs an!

void ausgebenMatrix(){
  sendData(0x08,z_std/10);
  sendData(0x07,z_std%10);
  sendData(0x05,z_min/10);
  sendData(0x04,z_min%10);
  sendData(0x02,z_sek/10);
  sendData(0x01,z_sek%10);
}

#include <Wire.h> // Wire Bibliothek einbinden
#include <LiquidCrystal_PCF8574.h>
#include <SPI.h>
LiquidCrystal_PCF8574 lcd (0x27); // LCD-Adresse auf 0x27 für 16 Zeichen und 2 Zeilen ein

#define MENU_S PC13 // Menu-Umschalter entprellter Taster auf Board, Low aktiv
#define S2 PA1 // Zählt den einzustellenden Wert hoch, (pellt), High aktiv, benötigt PullDown
#define CS  D10 // CS Signal auf D10
typedef enum {INTRO,STUNDEN_STELLEN,MINUTEN_STELLEN,SEKUNDEN_STELLEN,ZEIT_ANZEIGEN} zustandstyp;  // Aufzaehlungstyp
zustandstyp zustand = INTRO; // Startzustand
HardwareTimer sekTimer = HardwareTimer(TIM2);
char buf[16]; // Pufferspeicher bei Verwendung von sprintf

volatile int z_sek=0,z_min=0,z_std=0;  // Zeit
void ausgebenLCD_Menu(){ // das Menu zum Zeiteinstellen
  lcd.setCursor(0,0);
  switch(zustand){
    case INTRO:
      lcd.print("Uhr stellen...  ");
      lcd.setCursor(0, 1);
      lcd.print("weiter mit MENU_S   ");
      break;
    case STUNDEN_STELLEN:
      //lcd.printf("Std => S2: %02u  ",z_std);
      sprintf(buf,"Std => S2: %02u  ",z_std); // mit sprintf
      lcd.print(buf);
      break;
    case MINUTEN_STELLEN:
      lcd.printf("Min => S2: %02u",z_min);  // mit printf
      break;
    case SEKUNDEN_STELLEN:
      lcd.printf("Sec => S2: %02u",z_sek);
      break;
    case ZEIT_ANZEIGEN:
      lcd.print("    Uhrzeit     ");
      break;
  }
}
void ausgebenLCD_Uhrzeit(){ // Uhrzeit wird in Zeile 1 ausgegeben
  lcd.setCursor(0,1);
  lcd.printf("%02u : %02u : %02u    ", z_std, z_min, z_sek);
}
void ausgebenLED_Sekunden(){ // Ausgabe auf PORTC 
  GPIOC->ODR= (z_sek/10)<<4 | z_sek%10;
}
void sendData (unsigned char msb, unsigned char lsb){ // Hilfsfunktion zur Datenuebertragung
  digitalWrite(CS, LOW); // Uebertragung beginnt
  SPI.transfer(msb); // 8 Bit Transfer MSB      
  SPI.transfer(lsb); // 8 Bit Transfer LSB
  //SPI.transfer16(msb<<8 | lsb); // 16 Bit Transfer
  digitalWrite(CS, HIGH); // Uebertragung fertig, uebernehme Daten!
}
void ausgebenMatrix(){ // Zeit als BCD auf Matrix ausgeben
  sendData(0x08,z_std/10);
  sendData(0x07,z_std%10);
  sendData(0x05,z_min/10);
  sendData(0x04,z_min%10);
  sendData(0x02,z_sek/10);
  sendData(0x01,z_sek%10);
}
void isr_Menu(){ // schaltet das Menu der Zeiteingabe weiter
  switch(zustand){
    case INTRO:
      zustand=STUNDEN_STELLEN;
      break;
    case STUNDEN_STELLEN:
      zustand=MINUTEN_STELLEN;
      break;
    case MINUTEN_STELLEN:
      zustand=SEKUNDEN_STELLEN;
      break;
    case SEKUNDEN_STELLEN:
      sekTimer.resume();
      zustand=ZEIT_ANZEIGEN;
      break;
    case ZEIT_ANZEIGEN:
      sekTimer.pause();
      zustand=INTRO;
  }
  ausgebenLCD_Menu();
}
void isr_S2(){ // Einstellen der Werte
  switch(zustand){
    case INTRO:
    break;
    case STUNDEN_STELLEN:
      if(z_std>=23) z_std=0;
      else z_std++;
      break;
    case MINUTEN_STELLEN:
      if(z_min>=59) z_min=0;
      else z_min++;
      break;
    case SEKUNDEN_STELLEN:
      if(z_sek>=59) z_sek=0;
      else z_sek++;
      break;  
  }
  ausgebenLCD_Menu();
}
void incUhrzeit(){ // erhöht z_sek und passt z_min und z_std an
  z_sek++;
  if(z_sek>59){
    z_sek=0;
    z_min++;
    if(z_min>59){
      z_min=0;
      z_std++;
      if(z_std>23){
        z_std=0;
      }
    }
  }
}
void isr_sekTimer(){ // wird jede Sekunde aufgerufen
  incUhrzeit();
  ausgebenLCD_Uhrzeit();
  ausgebenLED_Sekunden();
  ausgebenMatrix();
}
void setup() {
  pinMode(PC0, OUTPUT);  // ohne diese Zeile klappts nicht
  GPIOC->MODER = 0x5555; // PC0..PC7 als Ausgang
  lcd.begin(16, 2); // initialize the lcd
  lcd.clear();
  lcd.setBacklight(255);
  //Serial.begin(9600);
  //Serial.printf("%02u : %02u : %02u\n", z_std, z_min, z_sek);
  pinMode(MENU_S,INPUT); // nicht unbedingt erforderlich da Userbutten PullUps hat
  attachInterrupt (digitalPinToInterrupt (MENU_S), isr_Menu, FALLING);
  pinMode(S2,INPUT_PULLDOWN); // PA1 auf Sturm-Board braucht Pulldown
  attachInterrupt (digitalPinToInterrupt (S2), isr_S2, RISING);
  // 32MHZ/3200 -> 10kHz 1/10kHz = 100µs 10000*100µs = 1s
  /*sekTimer.setPrescaleFactor(3200); // 0-65535
  sekTimer.setOverflow(10000);    //0-65535 => Prescaler AKTIV!
  */
  sekTimer.setOverflow(1, HERTZ_FORMAT); // lass die API rechnen

  sekTimer.attachInterrupt(isr_sekTimer); // Interrupt einstellen
  //ausgebenLCD_Menu();
  //sprintf(buf,"Hallo"); 
  //I2C_LCD(buf); // Fehler!
  pinMode(CS, OUTPUT); // CS-Pin initialisieren
  digitalWrite(CS, HIGH); // bei SPI_MODE0 ist CS in Ruhe high
  SPI.begin();  // SPI-Schnittstelle einrichten fuer MAX7219
  SPI.setBitOrder(MSBFIRST);            // Hoechstwertiges Bit zuerst
  SPI.setClockDivider(SPI_CLOCK_DIV32); // SCK mit 1 MHz, koennte auch 10 MHz
  SPI.setDataMode(SPI_MODE0);           // SCK in Ruhe Low, Uebername bei steigender Flanke
  delay(10); // kurz warten bis verdaut..
  // MAX7219 Initialisierung des Chips
  sendData(0x09, 0x00); // Decoding:     Aus: keine BCD Dekodierung fuer 7 Segment
  sendData(0x0A, 0x05); // Intesity:     Helligkeit auf 5 von 15 einstellen
  sendData(0x0B, 0x07); // Scan Limit:   Es sind 8 Zeilen mit LEDs
  sendData(0x0C, 0x01); // Shutdown:     Bit0 = 1: Normal operation mode, kein Ruhezustand
  sendData(0x0F, 0x01); // Display Test: Bit0 = 1: Displaytest An: Alle LEDs an!
  delay(300); // 500 ms delay
  sendData(0x0F,0x00);  // Display Test: Bit0 = 0: Displaytest Aus: Anzeigen was in Register steht
  for(int adr=1; adr<=8; adr++){ // alle LEDs ausschalten, sonst wird zufaelliges Muster ausgegeben
    sendData(adr,0x00);         // Zeile = 0
  }
  delay(200); // 500 ms delay
  ausgebenLCD_Menu();
}
void loop() { 
}

1. Die Widerstände R1 und R2 sind PullUp-Widerstände. Bei I2C werden OpenDrain-Ausgänge für SCL und SDA verwendet damit haben bei sperrenden Transistoren die Leitungen den Zustand High und sind nicht undefiniert / floating.
2. Bei SDO auf GND ergibt sich 0b1110110 = 0x76. Bei SDO auf VDD 0x77.
3. Beim Schreiben von Daten auf den Sensor wird vom Master nach der Startbedingung zuerst die Sensoradresse mit Schreibbit gesendet. Der Sensor antwortet durch SDA nach GND ziehen mit Acknowledge. Danach sendet der Master jeweils Byte-Paare bestehend aus Registeradresse und Daten zum Slave. Der Slave Quittiert den Empfang mit ACK. Nach dem letzten Paar wird die Stoppbedingung gesendet. Besonders ist bei diesem Baustein das zu jedem Datum zuerst das Zielregister angegeben werden muss und nicht einfach intern ein Pointer hochgezählt wird (not auto-incremented).
4. Beim Lesen von Daten wird zuerst die Adresse des Startregisters an den Sensor geschickt. Danach werden Datenbytes angefordert. Beginnend mit dem Startregister überträgt der Sensor die Daten zum Master. Dabei wird die Register-/Pointeradresse laufend erhöht (auto-incremented).

Der Unterschied ist der Zustand von SCK in Ruhe, also solange CSB High ist. Die Gemeinsamkeit ist die Übernahme der Daten bei steigender Flanke.

ToDo Bild

Kaskadieren funktioniert nicht, da der Sensor die über SDI empfangene Registeradresse und Schreibrichtung nicht an SDO durchreicht. Somit kann ein in der Kaskade nachgelagerter Sensor nicht sinnvoll angesprochen werden.

Beim Schreiben auf den Sensor wird nach Auswählen des Sensors durch CSB auf Low Byte-Paare aus Registeradresse (Control byte) MSB ist dabei Low und Daten gesendet. Am Ende wird CSB wieder auf High geschaltet. Beim Lesen wird nach Auswählen des Sensors durch CSB auf Low die Startadresse mit gesetztem MSB gesendet und danach sendet der Sensor mit jedem weiteren Takt die Inhalte der Register, die Registeradressen werden dabei automatisch erhöht.